; NAME: read_rcm_grid
;   
; PURPOSE: reads rcm_grid output file
;   
; Inputs:
;   file - path to rcm_grid file
;   offset - handle offset location (NOT USED)
;
; Outputs:
;   phi - phi values on grid (0-360 where 0 is noon)
;   theta - theta values on grid
;   alam - energy invariant (lambda) channels
;   kspec - type of species (1-electron, 2-proton) for energy channel
;   lon - longitude for each grid position
;   colat - colatitude for each grid position
;
; Author:
;   W. Douglas Cramer
;
pro read_rcm_grid, file, phi, theta, alam, kspec, lon, colat, offset=offset

  if (n_elements(offset) ne 1) then offset=0.0

  name=bytarr(80)
  sentinel=0l
  dummy=0l
  nphi=0l
  ntheta=0l
  maxfl=0l

  openr,fileid,file,/get_lun

  readu,fileid,sentinel

  ;read lon
  readu,fileid,dummy ;2 dims
  readu,fileid,nphi
  readu,fileid,ntheta
  readu,fileid,name
  lon=fltarr(nphi,ntheta)
  readu,fileid,lon

  ;read colat
  readu,fileid,dummy ;2 dims
  readu,fileid,nphi
  readu,fileid,ntheta
  readu,fileid,name
  colat=fltarr(nphi,ntheta)
  readu,fileid,colat

  ;read alam
  readu,fileid,dummy ;1 dims
  readu,fileid,maxfl
  readu,fileid,name
  alam=fltarr(maxfl)
  readu,fileid,alam

  ;read kspec
  readu,fileid,dummy ;1 dims
  readu,fileid,maxfl
  readu,fileid,name
  kspec=fltarr(maxfl)
  readu,fileid,kspec

  close,fileid
  free_lun,fileid

  ;extract theta, phi
  if (offset eq 0.0) then begin
    theta=reform(colat[0,*])
    phi=reform(lon[*,0])
  endif else begin
    stop,'ERROR: cant handle offset ne 0 yet (see utils.f90 in target-build/rcm)'
  endelse
end